금성과 목성의 만남 2015 - IDL/ENVI User Group

2015년 6월말~7월초에 금성과 목성이 아주 가까이 위치하는 현상이 있습니다. 우주쇼라고 언론에서 얘기하지만 행성들이 한 방향에 모이는 일은 가끔 있는 일입니다. 이번 이벤트는 금성과 목성이라는, 지구에서 보기에 가장 밝은 두 행성이 모이는 일이고, 초저녁에, 그리고 여름에, 해가 지고나서 비교적 오랜동안 하늘에서 볼 수 있는 이벤트라는 점에서 훌륭한 관측 기회였다고 생각합니다.

금성은 내행성으로 초저녁 또는 새벽에만 볼 수 있습니다. 새벽보다는 초저녁이 인간적으로 접근하기 쉽지요.
겨울보다는 여름이 분명 밖에 나가 하늘을 보기 쉽습니다. 또한 여름에는 태양과 행성이 지표면과 큰 각도를 이루며 뜨고 지기 때문에 해가 지고 난 후에 금성이 비교적 높은 고도에 남아 있습니다. 낮은 고도(지표면 가까이)보다는 훨씬 보기 편한 상황입니다.
2015년 6월말~7월초는 금성과 태양이 이루는 각거리가 의 최대이각에 가까운, 금성으로서는 가장 태양에서 멀리 떨어지는 때입니다. 태양에 가까우면(또는 달에 가까우면) 보기 어렵게 되죠. 태양이나 달에 묻혀 버리게 되니까요. (내행성인 금성은 태양에서 가장 멀리 떨어져봐야 대략 45도 정도입니다. 수성은 20도 정도이고 타원궤도상 가장 멀리 각을 잡더라도 30도가 안된다고 하네요).

개인적으로 천문학에 관심있는 친구들을 많이 두고 있는 덕분에 페이스북에서 금성과 목성이 가까이 접근해 있는 사진들을 많이 볼 수 있었습니다. 저는 실내에서만 술을 먹기 때문에 직접 이 현상을 보지는 못했습니다만, 금성과 목성은 밤하늘에서 달 빼면 가장 밝은 놈들이므로 분명히 잘 보였을 거라고 생각합니다.

Stellarium에서 재현한 7월 2일 저녁 금성과 목성

요즘 대세인 Stellarium (http://www.stellarium.org/)에서 7월 2일의 초저녁 서쪽하늘을 재현해 보면 금성과 목성이 아주 가까이, 그리고 금성 치고는 아주 높은 곳에서 빛나고 있는 것을 볼 수 있습니다. 이런 현상을 앞으로 또 언제 볼 수 있을까요?

IDL Astronomy Library를 이용해서 10년동안의 금성과 목성의 각거리를 계산해 보았습니다. 말이 계산해 본 것이지 IDL Astronomy Library가 제공하는 기능을 그냥 쓰면 되는 수준입니다. 다음과 같은 루틴을 사용합니다.

planet_coords : 날짜시간과 행성을 지정해 주면 이에 대한 적경, 적위 좌표를 계산해 줍니다. 전통적인 좌표계산 알고리즘을 사용하므로 태양에 가까이 있는 행성들(화성까지)에 대해서는 2050년 이내에 1분 이내의 오차, 그 밖으로는 10분 이내의 오차를 가진다고 합니다. JPL 키워드를 사용하면 JPL 궤도력을 이용해서 좀 더 정확한 위치 계산을 할 수 있다고 합니다. 오늘 시도하고자 하는 일에는 필요치 않아요.
sunpos : 날짜시간을 알려주면 태양의 적경, 적위 좌표를 계산해 줍니다.
sphdist : 구면상의 두 지점에 대한 각거리를 계산해 줍니다.

다음과 같이 프로그램을 만들어 보았습니다. 2015년 1월 1일부터 2025년 12월 31일까지 금성과 목성의 하늘에서의 위치를 계산하고, 이 둘간의 거리를 계산합니다. 태양의 위치도 계산하여 금성과 태양간의 거리도 계산합니다(태양에 금성이 가까우면 못보는 거예요). 이 데이터에서 금성과 목성의 거리가 1도 이내로 들어오는 날들을 뽑아 보았습니다.

pro distance_venus_jupiter

start=julday(1, 1, 2015)
final=julday(12, 31, 2025)
times=timegen(start=julday(1, 1, 2015), final=julday(12, 31, 2024), step=1, unit='day')

planet_coords, times, RA_venus, DEC_venus, /JD, planet='venus'
planet_coords, times, RA_jupiter, DEC_jupiter, /JD, planet='jupiter'
dist_venus_jupiter=sphdist(RA_venus, Dec_venus, RA_jupiter, Dec_jupiter, /Degree)
sunpos, times, ra_sun, dec_sun
dist_venus_sun=sphdist(ra_venus, dec_venus, ra_sun, dec_sun, /degree)

ok=where(dist_venus_jupiter lt 1, count)
for i=0, count-1 do begin
  print, times[ok[i]], dist_venus_jupiter[ok[i]], ra_sun[ok[i]], ra_venus[ok[i]], $
     dist_venus_sun[ok[i]], format='(C(CYI04,"/",CMOI02,"/",CDI02), 4(x,f10.5))'
endfor

xtickformat='(C(CYI04))'
w=window(dimension=[800, 400])
p1=plot(times, dist_venus_jupiter, current=w, $
  xtickformat=xtickformat, yrange=[0, 5], title='Dist. Venus & Jupiter',$
  xtitle='Date', ytitle='Dist.($\deg$)')
end

pro distance_venus_jupiter

start=julday(1, 1, 2015)

final=julday(12, 31, 2025)

times=timegen(start=julday(1, 1, 2015), final=julday(12, 31, 2024), step=1, unit='day')

planet_coords, times, RA_venus, DEC_venus, /JD, planet='venus'

planet_coords, times, RA_jupiter, DEC_jupiter, /JD, planet='jupiter'

dist_venus_jupiter=sphdist(RA_venus, Dec_venus, RA_jupiter, Dec_jupiter, /Degree)

sunpos, times, ra_sun, dec_sun

dist_venus_sun=sphdist(ra_venus, dec_venus, ra_sun, dec_sun, /degree)

ok=where(dist_venus_jupiter lt 1, count)

for i=0, count-1 do begin

print, times[ok[i]], dist_venus_jupiter[ok[i]], ra_sun[ok[i]], ra_venus[ok[i]], $

dist_venus_sun[ok[i]], format='(C(CYI04,"/",CMOI02,"/",CDI02), 4(x,f10.5))'

endfor

xtickformat='(C(CYI04))'

w=window(dimension=[800, 400])

p1=plot(times, dist_venus_jupiter, current=w, $

xtickformat=xtickformat, yrange=[0, 5], title='Dist. Venus & Jupiter',$

xtitle='Date', ytitle='Dist.($\deg$)')

end

금성과 목성의 각거리(Y 축범위 0~5도)

맨 왼쪽의 피크가 2015년 7월 1일입니다. 이런 식으로 조사해 보니 10년간에 유사한 이벤트가 일단 7회 정도 발생하는 군요(금성과 목성이 1도 이내로 가까워지는)

2015/06/29    0.92734   98.10545  142.80389   42.71788
2015/06/30    0.47625   99.14064  143.44710   42.45766
2015/07/01    0.37588  100.17483  144.07000   42.18038
2015/07/02    0.74246  101.20794  144.67205   41.88539
2016/08/27    0.49039  156.49243  177.34035   21.98580
2016/08/28    0.53645  157.40434  178.45511   22.24384
2017/11/12    0.97648  227.84899  214.15191   14.31930
2017/11/13    0.27662  228.86927  215.35711   14.07147
2021/02/11    0.43991  325.31924  314.90494   10.86367
2022/04/30    0.36733   37.71835  357.97257   42.90937
2022/05/01    0.67953   38.67370  359.03514   42.74541
2023/03/01    0.82456  342.12136   10.29899   30.30315
2023/03/02    0.59259  343.05764   11.40969   30.52142
2024/05/22    0.83124   59.78339   55.86876    3.93190
2024/05/23    0.26825   60.79009   57.13210    3.65996
IDL>

2015/06/29 0.92734 98.10545 142.80389 42.71788

2015/06/30 0.47625 99.14064 143.44710 42.45766

2015/07/01 0.37588 100.17483 144.07000 42.18038

2015/07/02 0.74246 101.20794 144.67205 41.88539

2016/08/27 0.49039 156.49243 177.34035 21.98580

2016/08/28 0.53645 157.40434 178.45511 22.24384

2017/11/12 0.97648 227.84899 214.15191 14.31930

2017/11/13 0.27662 228.86927 215.35711 14.07147

2021/02/11 0.43991 325.31924 314.90494 10.86367

2022/04/30 0.36733 37.71835 357.97257 42.90937

2022/05/01 0.67953 38.67370 359.03514 42.74541

2023/03/01 0.82456 342.12136 10.29899 30.30315

2023/03/02 0.59259 343.05764 11.40969 30.52142

2024/05/22 0.83124 59.78339 55.86876 3.93190

2024/05/23 0.26825 60.79009 57.13210 3.65996

IDL>

첫번째 컬럼은 날짜, 두번째 컬럼은 목성과 금성의 각거리(도 단위 1도 이내만 표출), 세번째 컬럼은 태양의 적경, 네번째 컬럼은 금성의 적경, 다섯번째 컬럼은 금성과 태양의 각거리입니다.

2015년 7월 1일 : 단연코 가장 좋은 관측 여건입니다. 여름이고, 저녁에 서쪽하늘에서 볼 수 있으며 태양과도 충분한 각(42도. 최대이각 45도에 근접하는)을 이룹니다.
2016년 8월 27일 : 역시 저녁에 볼 수 있으나 하지에서 좀 멀어진 여름이고, 태양과의 각(22도)이 큰 편은 아닙니다. 즉, 관측할 수 있는 시간이 짧아지고, 지평선에서 높지 않은 곳에서 관측할 수 있게 됩니다.
2017년 11월 13일 : 새벽에 볼 수 있습니다(태양의 적경이 금성의 적경보다 더 큽니다. 금성이 먼저 뜨고 진다는 얘기예요). 금성과 목성은 상당히 근접하는 것으로 보이나, 아쉽게도 태양과 가까이 있을 때입니다. 금성, 목성은 워낙 밝기 때문에 잠깐이나마 볼 수는 있을 거라고 생각합니다만, 새벽에 누가 일어나나요?
2021년 2월 11일 : 새벽입니다. 게다가 태양과 이루는 각이 11도가 안되네요.
2022년 4월 30일 : 6월말 7월초에 비하면 고도가 낮겠지만, 태양과 금성의 거리가 43도로 비교적 좋습니다. 아쉽게도 새벽이네요. 저는 포기합니다.
2023년 3월 2일 : 저녁때 볼 수 있습니다. 올 해 만큼은 아니겠지만 볼만한 조건일 것 같습니다.
2024년 5월 23일 : 금성과 목성은 아주 가까이 들러 붙는 것으로 나옵니다만, 태양도 여기에 들러 붙습니다. 관측은 어려울 것 같습니다(2024년에는 집집마다 코로나그래프를 구비하고 있을지도 모르죠).

이 계산은 수분 정도의 오차가 있을 것이고, 계산도 하루 단위로 수행했습니다. 때가 다가오면 우리나라 천문연구원에서 정확한 계산을 해서 알려 줄 것이기 때문에 정확히 계산하려고 노력하지는 않았습니다. 다만, 2015년 지금 보이는 목성과 금성의 접근은, 앞으로 10년 동안 가장 보기 좋은 이벤트였던 것 같네요. 최근접 시각은 지났더라도 7월 초라면 충분히 의미있는 장면(1도가 넘더라도 맨눈으로는 아주 가까이 있는 것으로 보입니다)을 보실 수 있으니 저녁에 야외에 계시다면 서쪽하늘을 한번 보시는 것이 좋겠습니다. 밤하늘에서 목성과 금성은 압도적으로 밝기 때문에 못찾을 리가 없습니다.